DaborTech

; ==============================================================================
; قسم إعدادات البرامج (قم بتعديل هذه البيانات مع كل برنامج جديد ترغب بعمله)
; ==============================================================================
#define AppTitle "DaborTech Silent Installer"
#define AppVer   "2.0.2.7"
#define AppPub   "DaborTech Clean Software Solutions"
#define AppURL   "https://t.me/DaborTech"
#define OutName  "DaborTech Silent Installer"

[Setup]
AppName={#AppTitle}
AppVersion={#AppVer}
AppPublisher={#AppPub}
AppPublisherURL={#AppURL}
VersionInfoCompany={#AppPub}
VersionInfoProductName={#AppTitle}
VersionInfoDescription={#AppTitle}
VersionInfoProductVersion={#AppVer}
VersionInfoVersion={#AppVer}
VersionInfoTextVersion={#AppVer}
VersionInfoCopyright=Copyright © 2027 DaborTech.
PrivilegesRequired=admin
ArchitecturesInstallIn64BitMode=x64compatible
DefaultDirName={tmp}\DaborTech
CreateAppDir=no
OutputDir=OutPut
OutputBaseFilename={#OutName}
Compression=zip/9
SolidCompression=yes
WizardStyle=modern
SetupIconFile=icon.ico
ShowLanguageDialog=no
DisableStartupPrompt=yes
DisableWelcomePage=yes
DisableDirPage=yes
DisableProgramGroupPage=yes
DisableFinishedPage=yes
Uninstallable=no
CloseApplications=no
RestartApplications=no
RestartIfNeededByRun=no

[Files]
Source: "DT-Silent.bat"; DestDir: "{tmp}"; Flags: ignoreversion
Source: "FileBin\*"; DestDir: "{tmp}\FileBin"; Flags: ignoreversion recursesubdirs createallsubdirs

[Run]
Filename: "{cmd}"; Parameters: "/c ""{tmp}\DT-Silent.bat"""; WorkingDir: "{tmp}"; Flags: runhidden waituntilterminated

[Code]
function PostMessage(hWnd: HWND; Msg: UINT; wParam: LongInt; lParam: LongInt): Boolean;
  external 'PostMessageW@user32.dll stdcall';
function ShowWindow(hWnd: HWND; nCmdShow: Integer): BOOL;
  external 'ShowWindow@user32.dll stdcall';
const
  BM_CLICK = $00F5;
procedure HideWizardWindow();
begin
  WizardForm.Left := -32000;
  WizardForm.Top := -32000;
  ShowWindow(WizardForm.Handle, 0);
end;
procedure InitializeWizard();
begin
  HideWizardWindow();
end;
procedure CurPageChanged(CurPageID: Integer);
begin
  HideWizardWindow();
  if CurPageID = wpReady then
    PostMessage(WizardForm.NextButton.Handle, BM_CLICK, 0, 0);
end;